>LIST
 REM "Cli"
[OPT Pass
\
\    Command Line Interpreter
\
\
\ Enters here with X pointing to the first command
\ allowable in this context, as an offset from the start of
\ the command table. (zp0),Y points to the command to be examined
\ Table format is command text followed by a byte with the top
\ bit set (this may have syntax encoded in it later)
\ this is followed by the two byte address of the routine in question.
\ Returns with carry set if unable to decode the command.
\ The table is terminated by &FF
\ Note that the command terminator byte may not be &FF
\
\
.cli
 STY scratch0\Save start of command for future use
\
.cli1 LDA (swzp0),Y\character
 AND #&5F\Force to upper case (weird if non alpha, but still not alpha)
 INX\to point to next table char
 INY\ready to go round loop
 EOR cmdtab-1,X\Devious, this bit ! (<cmdtab>-1 because X already inc'd)
\EOR because this leaves the top bit of table in N (top of A cleared
\earlier) but simultaneously leaves Z as the comparison result.
 BEQ cli1\Exactly the same - keep going
 BMI cli3\ Top bit set (in table version) - we have reached the end
\
\ At this point, we are in disagreement -
\ could be dot abbreviation, or a genuine mis-match.
\
 DEY\go back to the char in question
 LDA (swzp0),Y
 CMP #ASC"."
 BNE cli2\Definitely not OK now
  INY   \ SKIP OVER "." WHEN PASSING REST OF COMMAND LINE TO CLI
\
\ Now OK so skip to end of command
.cli5 INX
 LDA cmdtab-1,X\This is the same offset as above, so exit condition
\ has same X. Can't miss the end despite having inc'd X as we
\ would have found it straight away if the last match was with
\ the terminator.
 BPL cli5
 BMI cli4\Unconditional
\
\ Total failure if not dot abbreviation
\ so skip to next table entry
\
.cli2 INX
  LDA cmdtab-2,X\X has been incremented - on entry lowest value
\possible would be 2nd byte of dud cmd, highest would be
\pointing at lo byte of address, so at this point we either
\test one of the command bytes or the byte with top bit set.
 BPL cli2\Find byte with top bit set
 INX\X Now pointing at 1st byte of next cmd
 LDY scratch0\Get back pointer to command
 CMP cmdtab,X
 BCS cli1\Another devious one ... A is always >127 (we have just
\tested it), and <cmdtab>,X is either &FF = end of table, or is
\a character. If X=&FF, X is always >=A hence carry clear, if
\X=(character) then X<128 hence X<A hence carry set.
 RTS\Return with carry clear if command no good.
\
\
\ Gets here with command all matched, but must check for
\ next char non-alpha. X points to lo of execute address
\ Y was pointing to char of command which failed to match - terminator
\ or other - but has been inc'd.
\
.cli3
 DEY
 LDA (swzp0),Y
 CMP #ASC"A"
 BCC cli4\less
 CMP #ASC("z")+1\Cheating here - not checking for [\]^`
 BCC cli2\Definitely "alpha" or [\]^`
\
\ Enters here with comand fully checked, X points to lo of addr
\
.cli4
.spcs
 Lda (swzp0),Y
 Cmp #32
 Bne cli10
 Iny
 Jmp spcs
.cli10
 Tya
 Clc: Adc swzp0
 Sta zp0:sta cline \******* New store for command addr
 Lda swzp1
 Adc #0
 Sta zp1:sta cline+1
.ncy1
 LDA cmdtab,X
 STA swzp0
 LDA cmdtab+1,X
 STA swzp1
 JMP (swzp0) \Execute the command!
\
\
\
\
\
\
\
\
\
\
.cmdtab
 EQUS "DIR"
 EQUB &80+dirbit
 EQUW setdef
\
 EQUS "INFO"
 EQUB &80+filebit
 EQUW info
\
 EQUS "LIB"
 EQUB &80+dirbit
 EQUW lib
\
 EQUS "SHELL"
 EQUB &80+textbit
 EQUW shell
\
 EQUS "DELETE"
 EQUB &80+filebit
 EQUW delete
\
 EQUS "RENAME"
 EQUB &80+fromtobit
 EQUW rename
\
 EQUS "COPY"
 EQUB &80+fromtobit
 EQUW copy
\
.swcmds\These commands allowed at the sideways entry point.
\
 EQUS "TERMINAL"
 EQUB &80
 EQUW StartTerm
\
 EQUS "HOSTFS"
 EQUB &80
 EQUW select_fs
\
 EQUS "TYPE"
 EQUB &80+filebit
 EQUW Type
\
 EQUS "PRINT"
 EQUB &80+filebit
 EQUW Print
\
 EQUS "MOUSE"
 EQUB &80
 EQUW Init_mouse
\
 EQUS "JOYSTICK"
 EQUB &80
 EQUW Remove_mouse
\
 EQUB &FF \ End of table
\
\
\
\
]
RETURN